// Persistence Of Vision raytracer version 3.1 sample file.

// By Gian Marco Todesco


#include "shapes.inc"
#include "colors.inc"
#include "textures.inc"
#include "stones.inc"

#declare aspect_ratio = 285/400;       

#declare Cayley = cubic {     
   <-9, 0, -3, 36, 27, 
            0, 0, 0, 0, 0, 
            0, -3, 36, 0, 0, 
            0, 4, -16, 0, 0  
            > 
}

#declare BoundedCayley = intersection {
   object {Cayley }
   cylinder { <0,0,-10>, <0,0,10>, 6.5 } 
}
  
#declare Model = union {
   object {
        BoundedCayley 
        scale 0.4
        texture {
          pigment { colour White }
          finish {
            ambient 0.3
            diffuse 0.2
            specular 1
            phong 1
            roughness .0005            
          }        
        } 
   }
   superellipsoid { <.1, .25>  
        scale <3.4,3.4,0.5>
        translate -4.7*z
        pigment {colour 0.15*Red}
        finish {ambient 1}  
        rotate 60*z
   }
}


object {
  Model     
  translate 0.2*z
  rotate -40*z      
}

camera {
   location  <0.0, -20.0, 4.0>
   right     <aspect_ratio, 0.0,  0.0>
   up        <0.0, 0.0,  1.0>
   sky       <0.0, 0.0,  1.0>
   look_at   <0.0, 0.0,  0>  
   angle 21
}


  light_source { <10, -20, 10> colour White } 
  light_source { <-20,-30, 40> colour White } 
  light_source { <15, -20, 35> colour White } 
  light_source { <30, -20, 50> colour White }